subroutine CalcMajCompIceFrac( xy_SurfMajCompIce, xy_MajCompIceFrac )

    ! 格子点設定
    ! Grid points settings
    !
    use gridset, only: imax, jmax, kmax    ! 鉛直層数.
                               ! Number of vertical level

    ! 雪と海氷の定数の設定
    ! Setting constants of snow and sea ice
    !
    use constants_snowseaice, only: CO2IceThreshold


!!$    logical , intent(in ) :: xy_FlagLand      ( 0:imax-1, 1:jmax )
    real(DP), intent(in ) :: xy_SurfMajCompIce( 0:imax-1, 1:jmax )
    real(DP), intent(out) :: xy_MajCompIceFrac( 0:imax-1, 1:jmax )


    ! 作業変数
    ! Work variables
    !
    real(DP):: MajCompIceThreshold
    integer:: i               ! 経度方向に回る DO ループ用作業変数
                              ! Work variables for DO loop in longitude
    integer:: j               ! 緯度方向に回る DO ループ用作業変数
                              ! Work variables for DO loop in latitude

    ! 初期化確認
    ! Initialization check
    !
    if ( .not. snowice_frac_inited ) then
      call MessageNotify( 'E', module_name, 'This module has not been initialized.' )
    end if



    MajCompIceThreshold = CO2IceThreshold
    do j = 1, jmax
      do i = 0, imax-1

!!$        if ( xy_FlagLand(i,j) ) then
          xy_MajCompIceFrac(i,j) = ( xy_SurfMajCompIce(i,j) - 0.0_DP ) / ( MajCompIceThreshold    - 0.0_DP )
          xy_MajCompIceFrac(i,j) = max( min( xy_MajCompIceFrac(i,j), 1.0_DP ), 0.0_DP )
!!$        else
!!$          xy_MajCompIceFrac(i,j) = 0.0_DP
!!$        end if

      end do
    end do


  end subroutine CalcMajCompIceFrac

  subroutine CalcSeaIceFrac( xy_SeaIceConc, xy_SeaIceFrac )

    ! 格子点設定
    ! Grid points settings
    !
    use gridset, only: imax, jmax, kmax    ! 鉛直層数.
                               ! Number of vertical level

    ! 雪と海氷の定数の設定
    ! Setting constants of snow and sea ice
    !
    use constants_snowseaice, only: SeaIceThreshold


!!$    logical , intent(in ) :: xy_FlagOcean ( 0:imax-1, 1:jmax )
    real(DP), intent(in ) :: xy_SeaIceConc( 0:imax-1, 1:jmax )
    real(DP), intent(out) :: xy_SeaIceFrac( 0:imax-1, 1:jmax )


    ! 作業変数
    ! Work variables
    !
    integer:: i               ! 経度方向に回る DO ループ用作業変数
                              ! Work variables for DO loop in longitude
    integer:: j               ! 緯度方向に回る DO ループ用作業変数
                              ! Work variables for DO loop in latitude

    ! 初期化確認
    ! Initialization check
    !
    if ( .not. snowice_frac_inited ) then
      call MessageNotify( 'E', module_name, 'This module has not been initialized.' )
    end if


    do j = 1, jmax
      do i = 0, imax-1

!!$        if ( ( xy_FlagOcean(i,j) ) .and. &
!!$          &  ( xy_SeaIceConc(i,j) > SeaIceThreshold ) ) then
        if ( xy_SeaIceConc(i,j) > SeaIceThreshold ) then
          xy_SeaIceFrac(i,j) = 1.0_DP
        else
          xy_SeaIceFrac(i,j) = 0.0_DP
        end if

      end do
    end do


  end subroutine CalcSeaIceFrac

  subroutine CalcSnowFrac( xy_SurfSnow, xy_SnowFrac )

    ! 格子点設定
    ! Grid points settings
    !
    use gridset, only: imax, jmax, kmax    ! 鉛直層数.
                               ! Number of vertical level

    ! 雪と海氷の定数の設定
    ! Setting constants of snow and sea ice
    !
    use constants_snowseaice, only: SnowThreshold => ThresholdSurfSnow

!!$    logical , intent(in ) :: xy_FlagLand( 0:imax-1, 1:jmax )
    real(DP), intent(in ) :: xy_SurfSnow( 0:imax-1, 1:jmax )
    real(DP), intent(out) :: xy_SnowFrac( 0:imax-1, 1:jmax )


    ! 作業変数
    ! Work variables
    !
    integer:: i               ! 経度方向に回る DO ループ用作業変数
                              ! Work variables for DO loop in longitude
    integer:: j               ! 緯度方向に回る DO ループ用作業変数
                              ! Work variables for DO loop in latitude

    ! 初期化確認
    ! Initialization check
    !
    if ( .not. snowice_frac_inited ) then
      call MessageNotify( 'E', module_name, 'This module has not been initialized.' )
    end if


    do j = 1, jmax
      do i = 0, imax-1

!!$        if ( xy_FlagLand(i,j) ) then
          xy_SnowFrac(i,j) = ( ( xy_SurfSnow(i,j) - 0.0_DP ) / ( SnowThreshold  - 0.0_DP ) )**NOrd
          xy_SnowFrac(i,j) = max( min( xy_SnowFrac(i,j), 1.0_DP ), 0.0_DP )
!!$        else
!!$          xy_SnowFrac(i,j) = 0.0_DP
!!$        end if

      end do
    end do


  end subroutine CalcSnowFrac

  function SeaIceAboveThreshold( SeaIceConc ) result( FlagExist )

    ! 雪と海氷の定数の設定
    ! Setting constants of snow and sea ice
    !
    use constants_snowseaice, only: SeaIceThreshold

    real(DP), intent(in) :: SeaIceConc

    logical :: FlagExist


    if ( SeaIceConc > SeaIceThreshold ) then
      FlagExist = .true.
    else
      FlagExist = .false.
    end if

  end function SeaIceAboveThreshold

  subroutine SnowIceFracInit

    ! モジュール引用 ; USE statements
    !

    ! 種別型パラメタ
    ! Kind type parameter
    !
    use dc_types, only: STDOUT ! 標準出力の装置番号. Unit number of standard output

    ! ファイル入出力補助
    ! File I/O support
    !
    use dc_iounit, only: FileOpen

    ! NAMELIST ファイル入力に関するユーティリティ
    ! Utilities for NAMELIST file input
    !
    use namelist_util, only: namelist_filename, NmlutilMsg


    ! 作業変数
    ! Work variables
    !
    integer:: unit_nml        ! NAMELIST ファイルオープン用装置番号.
                              ! Unit number for NAMELIST file open
    integer:: iostat_nml      ! NAMELIST 読み込み時の IOSTAT.
                              ! IOSTAT of NAMELIST read


    ! NAMELIST 変数群
    ! NAMELIST group name
    !
    namelist /snowice_frac_nml/ NOrd

    ! 実行文 ; Executable statement
    !


    if ( snowice_frac_inited ) return


    ! デフォルト値の設定
    ! Default values settings
    !
    NOrd = 2.0_DP


    ! NAMELIST の読み込み
    ! NAMELIST is input
    !
    if ( trim(namelist_filename) /= '' ) then
      call FileOpen( unit_nml, namelist_filename, mode = 'r' ) ! (in)

      rewind( unit_nml )
      read( unit_nml, nml = snowice_frac_nml, iostat = iostat_nml )
      close( unit_nml )

      call NmlutilMsg( iostat_nml, module_name ) ! (in)
      if ( iostat_nml == 0 ) write( STDOUT, nml = snowice_frac_nml )
    end if

    ! 印字 ; Print
    !
    call MessageNotify( 'M', module_name, '----- Initialization Messages -----' )
    call MessageNotify( 'M', module_name, 'NOrd = %f', d = (/NOrd/) )
    call MessageNotify( 'M', module_name, '-- version = %c', c1 = trim(version) )


    snowice_frac_inited = .true.

  end subroutine SnowIceFracInit